Τώρα είναι Πέμ 28 Μαρ 2024 07:25 pm

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]




Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 1 Δημοσίευση ] 
Συγγραφέας Μήνυμα
 Θέμα δημοσίευσης: Προσομοίωση - Θέμα 3
ΔημοσίευσηΔημοσιεύτηκε: Παρ 25 Ιούλ 2008 10:28 pm 
Χωρίς σύνδεση

Εγγραφή: Κυρ 12 Οκτ 2003 01:52 am
Δημοσιεύσεις: 189
Τοποθεσία: ΝΙΚΑΙΑ - ΠΕΙΡΑΙΑΣ
Syntax: [ Download ] [ Hide ]
! ====================================================================================================
!  ΠΡΟΣΟΜΟΙΩΣΗ 2008 - ΘΕΜΑ 3
! ====================================================================================================
! Μια εταιρία εμπορίας και πώλησης ηλεκτρονικών υπολογιστών απασχολεί έναν αριθμό υπαλλήλων στον
! τομέα της πώλησης οθονών. Κάθε ένας από τους υπαλλήλους αυτούς αμείβεται με βασικό μισθό 1000 ευρώ
! που προσαυξάνεται κλιμακωτά ανάλογα με τις μηνιαίες πωλήσεις που πραγματοποιεί.
! Το bonus που αντιστοιχεί σε κάθε υπάλληλο με βάση τον αριθμό των οθονών που πούλησε, υπολογίζεται
! με βάση τον παρακάτω πίνακα:
!
!                        Αριθμός Οθονών που πούλησε  Βonus για κάθε οθόνη
!                                    1 - 50                 1,5 €
!                                   51 - 100                3   €
!                                   101 και άνω             3,5 €
!
! Για παράδειγμα: Αν ένας υπάλληλος πούλησε 52 οθόνες σε ένα μήνα, το bonus που του αντιστοιχεί είναι:
!                                            50·1,5 + 2·3 = 75 + 6 = 81 €.
!
! 1. Να κατασκευάσετε πρόγραμμα το οποίο:
!     α) περιλαμβάνει τμήμα δηλώσεων.
!     β) Διαβάζει τα ονοματεπώνυμα πολλών υπαλλήλων και την ποσότητα των οθονών που πούλησε ο καθένας
!        και σταματά μόλις δοθεί ως ονοματεπώνυμο ο χαρακτήρας *.
!     γ) Καλεί υποπρόγραμμα που δέχεται ως είσοδο τον αριθμό των οθονών που πούλησε ο κάθε υπάλληλος
!        και επιστρέφει το bonus που του αντιστοιχεί.
!     δ) Εμφανίζει τον συνολικό μισθό κάθε υπαλλήλου (βασικό μισθό και bonus)
!     ε) Εμφανίζει το ποσοστό των υπαλλήλων με συνολικό μισθό μεγαλύτερο από 1200€.
!
! 2. Να κατασκευάσετε το υποπρόγραμμα που καλείται στο ερώτημα 1γ.
!=====================================================================================================

ΠΡΟΓΡΑΜΜΑ PR_08_3
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ : n , k , x    
  ΠΡΑΓΜΑΤΙΚΕΣ : s , b , y                                
  ΧΑΡΑΚΤΗΡΕΣ : name
ΑΡΧΗ
  n <-- 0   ! ΠΛΗΘΟΣ ΥΠΑΛΛΗΛΩΝ
  k <-- 0   ! ΠΛΗΘΟΣ ΥΠΑΛΛΗΛΩΝ ΜΕ ΜΙΣΘΟ > 1200
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΡΑΨΕ 'Δώσε ονοματεπώνυμο υπαλλήλου'
    ΔΙΑΒΑΣΕ name
    ΑΝ name <> '*' ΤΟΤΕ
      n <-- n + 1
      ΓΡΑΨΕ 'Πόσες οθόνες πούλησε;'
      ΔΙΑΒΑΣΕ x
      b <-- bonus(x)
      s <-- 1000 + b
      ΓΡΑΨΕ 'Ο υπάλληλος' , name , 'παίρνει' , s , 'ευρώ.'
      ΑΝ s > 1200 ΤΟΤΕ
        k <-- k + 1
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΑΝ
  ΜΕΧΡΙΣ_ΟΤΟΥ name = '*'
  y <-- 100*k/n
  ΓΡΑΨΕ 'το ποσοστό των υπαλλήλων με μισθό πάνω από 1200 ευρώ είναι' , y , '%'
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ

! ---- ΣΥΝΑΡΤΗΣΗ ----

ΣΥΝΑΡΤΗΣΗ bonus(x): ΠΡΑΓΜΑΤΙΚΗ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ : x
ΑΡΧΗ
  ΑΝ x <= 50 ΤΟΤΕ
    bonus <-- x*1.5
  ΑΛΛΙΩΣ_ΑΝ x <= 100 ΤΟΤΕ
    bonus <-- 50*1.5 + (x-50)*3
  ΑΛΛΙΩΣ
    bonus <-- 50*1.5 + 50*3 + (x-100)*3.5
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ
 


Κορυφή
 Προφίλ  
Απάντηση με παράθεση  
Τελευταίες δημοσιεύσεις:  Ταξινόμηση ανά  
Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 1 Δημοσίευση ] 

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]


Μέλη σε σύνδεση

Μέλη σε αυτή την Δ. Συζήτηση: Δεν υπάρχουν εγγεγραμμένα μέλη και 4 επισκέπτες


Δεν μπορείτε να δημοσιεύετε νέα θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να απαντάτε σε θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επεξεργάζεστε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να διαγράφετε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επισυνάπτετε αρχεία σε αυτή τη Δ. Συζήτηση

Αναζήτηση για:
Μετάβαση σε:  
cron
Προβολές: