! ===================================================================================================
! ΗΜΕΡΗΣΙΟ - ΙΟΥΛΙΟΣ 2007 - ΘΕΜΑ 3
! ===================================================================================================
!  Το κλασικό παιχνίδι "Πέτρα-Ψαλίδι-Χαρτί" παίζεται με δυο παίκτες. Σε κάθε γύρο του παιχνιδιού,
!  ο κάθε παίκτης επιλέγει ένα από τα ΠΕΤΡΑ, ΨΑΛΙΔΙ, ΧΑΡΤΙ, και παρουσιάζει την επιλογή του
!  ταυτόχρονα με τον αντίπαλο του. Η ΠΕΤΡΑ κερδίζει το ΨΑΛΙΔΙ, το ΨΑΛΙΔΙ το ΧΑΡΤΙ και το ΧΑΡΤΙ την
!  ΠΕΤΡΑ. Σε περίπτωση που οι δυο παίκτες έχουν την ίδια επιλογή, ο γύρος λήγει ισόπαλος.
!  Το παιχνίδι προχωράει με συνεχόμενους γύρους μέχρι ένας τουλάχιστον από τους παίκτες να αποχωρήσει
!  Νικητής αναδεικνύεται ο παίκτης με τις περισσότερες νίκες. Αν οι δυο παίκτες έχουν τον ίδιο αριθμό
!  νικών, το παιχνίδι λήγει ισόπαλο.
!  Να αναπτύξετε αλγόριθμο ο οποίος διαβάζει τα ονόματα των δυο παικτών και υλοποιεί το παραπάνω
!  παιχνίδι ως εξής:
!  Α. Για κάθε γύρο του παιχνιδιού:
!    1.  διαβάζει την επιλογή κάθε παίκτη, η οποία μπορεί να είναι μία από τις εξής:
!        ΠΕΤΡΑ, ΨΑΛΙΔΙ, ΧΑΡΤΙ, ΤΕΛΟΣ. (Δεν απαιτείται έλεγχος εγκυρότητας τιμών.)
!    2.  συγκρίνει τις επιλογές των παικτών και διαπιστώνει το νικητή του γύρου ή την ισοπαλία.
!  Β. Τερματίζει το παιχνίδι όταν ένας τουλάχιστον από τους δυο παίκτες επιλέξει ΤΕΛΟΣ.
!  Γ. Εμφανίζει το όνομα του νικητή ή, αν δεν υπάρχει νικητής, το μήνυμα "ΤΟ ΠΑΙΧΝΙΔΙ ΕΛΗΞΕ ΙΣΟΠΑΛΟ".
! ===================================================================================================

ΠΡΟΓΡΑΜΜΑ  HMER_JUL_2007_03
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: s1 , s2
  ΧΑΡΑΚΤΗΡΕΣ: name1 , name2 , a1 , a2
ΑΡΧΗ
  ΓΡΑΨΕ 'Δώσε τα ονόματα των παικτών'
  ΔΙΑΒΑΣΕ name1 , name2
  s1 <-- 0
  s2 <-- 0

  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΡΑΨΕ 'Δώσε την επιλογή του παίκτη' , name1
    ΔΙΑΒΑΣΕ a1
    ΓΡΑΨΕ 'Δώσε την επιλογή του παίκτη' , name2
    ΔΙΑΒΑΣΕ a2

    ΑΝ a1 <> 'ΤΕΛΟΣ' ΚΑΙ a2 <> 'ΤΕΛΟΣ' ΤΟΤΕ

      ΑΝ a1 = 'ΠΕΤΡΑ' ΤΟΤΕ
        ΑΝ a2 = 'ΨΑΛΙΔΙ' ΤΟΤΕ
          s1 <-- s1 + 1
        ΑΛΛΙΩΣ_ΑΝ a2 = 'ΧΑΡΤΙ' ΤΟΤΕ
          s2 <-- s2 + 1
        ΤΕΛΟΣ_ΑΝ
      ΑΛΛΙΩΣ_ΑΝ a1 = 'ΨΑΛΙΔΙ' ΤΟΤΕ
        ΑΝ a2 = 'ΧΑΡΤΙ' ΤΟΤΕ
          s1 <-- s1 + 1
        ΑΛΛΙΩΣ_ΑΝ a2 = 'ΠΕΤΡΑ' ΤΟΤΕ
          s2 <-- s2 + 1
        ΤΕΛΟΣ_ΑΝ
      ΑΛΛΙΩΣ
        ΑΝ a2 = 'ΠΕΤΡΑ' ΤΟΤΕ
          s1 <-- s1 + 1
        ΑΛΛΙΩΣ_ΑΝ a2 = 'ΨΑΛΙΔΙ' ΤΟΤΕ
          s2 <-- s2 + 1
        ΤΕΛΟΣ_ΑΝ
      ΤΕΛΟΣ_ΑΝ

    ΤΕΛΟΣ_ΑΝ

  ΜΕΧΡΙΣ_ΟΤΟΥ a1 = 'ΤΕΛΟΣ' ή a2 = 'ΤΕΛΟΣ'

  ΑΝ s1 > s2 ΤΟΤΕ
    ΓΡΑΨΕ 'Νικητής είναι ο' , name1
  ΑΛΛΙΩΣ_ΑΝ s2 > s1 ΤΟΤΕ
    ΓΡΑΨΕ 'Νικητής είναι ο' , name2
  ΑΛΛΙΩΣ
    ΓΡΑΨΕ 'To παιχνίδι έληξε ισόπαλο'
  ΤΕΛΟΣ_ΑΝ

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ