! ===============================================================================================
! ΗΜΕΡΗΣΙΟ - ΙΟΥΝΙΟΣ 2005 - ΘΕΜΑ 4
! ===============================================================================================
! Σε ένα διαγωνισμό συμμετέχουν 100 υποψήφιοι. Κάθε υποψήφιος διαγωνίζεται σε 50 ερωτήσεις
! πολλαπλής επιλογής.
! Να αναπτύξετε αλγόριθμο που να κάνει τα παρακάτω:
! α. Να καταχωρεί σε πίνακα AΠ[100,50] τα αποτελέσματα των απαντήσεων του κάθε υποψηφίου σε κάθε
! ερώτηση. Κάθε καταχώρηση μπορεί να είναι μόνο μία από τις παρακάτω:
! 1. Σ αν είναι σωστή η απάντηση
! 2. Λ αν είναι λανθασμένη η απάντηση και
! 3. Ξ αν ο υποψήφιος δεν απάντησε.
! Να γίνεται έλεγχος των δεδομένων εισόδου.
! β. Να βρίσκει και να τυπώνει τους αριθμούς των ερωτήσεων που παρουσιάζουν το μεγαλύτερο βαθμό
! δυσκολίας, δηλαδή έχουν το μικρότερο πλήθος σωστών απαντήσεων.
! γ. Αν κάθε Σ βαθμολογείται με 2 μονάδες, κάθε Λ με -1 μονάδα και κάθε Ξ με 0 μονάδες τότε :
! i. Να δημιουργεί ένα μονοδιάστατο πίνακα ΒΑΘ[100], κάθε στοιχείο του οποίου θα περιέχει
! αντίστοιχα τη συνολική βαθμολογία ενός υποψηφίου.
! ii. Να τυπώνει το πλήθος των υποψηφίων που συγκέντρωσαν βαθμολογία μεγαλύτερη από 50.
! ===============================================================================================
ΠΡΟΓΡΑΜΜΑ ΗΜ_2005_06_4
ΜΕΤΑΒΛΗΤΕΣ
ΑΚΕΡΑΙΕΣ: N[100] , ΒΑΘ[100] , i , j , min , k
ΧΑΡΑΚΤΗΡΕΣ: ΑΠ[100,50]
ΑΡΧΗ
ΓΡΑΨΕ 'Δώσε τις απαντήσεις των υποψηφίων'
ΓΡΑΨΕ 'Σ για σωστή , Λ για λάθος ή Ξ αν δεν απάντησε.'
ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 100
ΓΡΑΨΕ 'Υποψήφιος Νο : ',i
ΓΡΑΨΕ '========================='
ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 50
ΓΡΑΨΕ 'Ερώτηση :',j
ΔΙΑΒΑΣΕ ΑΠ[i,j]
ΟΣΟ ΑΠ[i,j] <> 'Σ' ΚΑΙ ΑΠ[i,j] <> 'Λ' ΚΑΙ ΑΠ[i,j] <> 'Ξ' ΕΠΑΝΑΛΑΒΕ
ΓΡΑΨΕ 'Λάθος. Ξαναδώσε ( Σ ή Λ ή Ξ )'
ΔΙΑΒΑΣΕ ΑΠ[i,j]
ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 50
N[j] <-- 0 ! Πλήθος σωστών απαντήσεων κάθε ερώτησης.
ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 100
ΑΝ ΑΠ[i,j] = 'Σ' ΤΟΤΕ
N[j] <-- N[j] + 1
ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
min <-- N[1]
ΓΙΑ j ΑΠΟ 2 ΜΕΧΡΙ 50
ΑΝ N[j] < min ΤΟΤΕ
min <-- N[j]
ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
ΓΡΑΨΕ 'Οι δυσκολότερες ερωτήσεις του διαγωνισμού είναι οι εξής :'
ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 50
ΑΝ N[j] = min ΤΟΤΕ
ΓΡΑΨΕ j
ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 100
ΒΑΘ[i] <-- 0
ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 50
ΑΝ ΑΠ[i,j] = 'Σ' ΤΟΤΕ
ΒΑΘ[i] <-- ΒΑΘ[i] + 2
ΑΛΛΙΩΣ_ΑΝ ΑΠ[i,j] = 'Λ' ΤΟΤΕ
ΒΑΘ[i] <-- ΒΑΘ[i] - 1
ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
k <-- 0
ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 100
ΑΝ ΒΑΘ[i] > 50 ΤΟΤΕ
k <-- k + 1
ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
ΓΡΑΨΕ k , 'υποψήφιοι πέτυχαν βαθμολογία πάνω από 50.'
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ