Τώρα είναι Παρ 29 Μαρ 2024 02:44 am

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]




Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 4 Δημοσιεύσεις ] 
Συγγραφέας Μήνυμα
 Θέμα δημοσίευσης: ΠΑΙΧΝΙΔΙ ΤΥΠΟΥ MASTER MIND
ΔημοσίευσηΔημοσιεύτηκε: Δευτ 05 Μάιος 2003 07:25 pm 
Χωρίς σύνδεση

Εγγραφή: Πέμ 01 Μάιος 2003 10:25 pm
Δημοσιεύσεις: 38
Τοποθεσία: Καλλιθέα Αττικής
Το παιχνίδι αυτό γράφτηκε για να πλουτίσουμε τα παιχνίδια της γλώσσας.
Άσκηση: Να φτιάξετε να εφαρμόζει βαθμολογία ανάλογα σε πόσα βήματα βρίσκουμε την λύση.

Syntax: [ Download ] [ Hide ]
ΠΡΟΓΡΑΜΜΑ MASTERMIND
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: Ι, Α, Ν, ΠΑΙΧΝΙΔΙ[4], ΑΛΛΟ, ΔΟΚΙΜΗ[4], ΣΕΙΡΑ
  ΛΟΓΙΚΕΣ: ΣΗΜΕΙΟ[10], ΕΝΤΑΞΕΙ, ΤΕΡΜΑΤΙΣΕ
  ΧΑΡΑΚΤΗΡΕΣ: ΓΡΑΜΜΗ[25], ΜΕΤ_Χ[10], ΛΥΣΗ

ΑΡΧΗ
  Α <-- 12123
  ΜΕΤ_Χ[1] <-- '0'
  ΜΕΤ_Χ[2] <-- '1'
  ΜΕΤ_Χ[3] <-- '2'
  ΜΕΤ_Χ[4] <-- '3'
  ΜΕΤ_Χ[5] <-- '4'
  ΜΕΤ_Χ[6] <-- '5'
  ΜΕΤ_Χ[7] <-- '6'
  ΜΕΤ_Χ[8] <-- '7'
  ΜΕΤ_Χ[9] <-- '8'
  ΜΕΤ_Χ[10] <-- '9'

  ΓΡΑΨΕ 'MASTER MIND'
  ΓΡΑΨΕ '-----------'
  ΑΝ ΝΑΙ('ΘΕΛΕΙΣ ΠΛΗΡΟΦΟΡΙΕΣ ΓΙΑ ΤΟ ΠΑΙΧΝΙΔΙ') ΤΟΤΕ
    ΓΡΑΨΕ 'ΕΧΟΥΜΕ ΔΕΚΑ ΨΗΦΙΑ 0..9'
    ΓΡΑΨΕ 'ΚΡΥΒΩ ΤΕΣΣΕΡΑ ΑΠΟ ΑΥΤΑ'
    ΓΡΑΨΕ 'ΠΡΕΠΕΙ ΝΑ ΒΡΕΙΣ ΠΟΙΑ ΕΙΝΑΙ'
    ΓΡΑΨΕ 'ΚΑΙ ΣΕ ΠΟΙΑ ΘΕΣΗ'
    ΓΡΑΨΕ 'ΣΕ ΚΑΘΕ ΑΠΑΝΤΗΣΗ ΣΟΥ...'
    ΓΡΑΨΕ 'ΣΟΥ ΛΕΩ ΠΟΣΑ ΒΡΗΚΕΣ ΜΕ ΣΗΜΑΔΙ %'
    ΓΡΑΨΕ 'ΚΑΙ ΠΟΣΑ ΣΕ ΣΩΣΤΗ ΘΕΣΗ ΜΕ ΣΗΜΑΔΙ *'
    ΓΡΑΨΕ 'ΑΛΛΑ ΤΑ ΣΗΜΑΔΙΑ ΕΙΝΑΙ ΣΕ ΤΥΧΑΙΕΣ ΘΕΣΕΙΣ'
    ΓΡΑΨΕ 'ΟΠΟΤΕ ΘΕΣ ΜΠΟΡΕΙ ΝΑ ΤΟ ΠΑΡΕΙ ΤΟ ΠΟΤΑΜΙ...'
    ΓΡΑΨΕ 'ΚΑΙ ΝΑ ΜΑΘΕΙΣ ΤΗΝ ΛΥΣΗ!'
  ΤΕΛΟΣ_ΑΝ
  ! ΑΡΧΙΚΟΠΟΙΗΣΗ (ΤΙΜΕΣ ΣΕ ΑΡΧΙΚΗ ΘΕΣΗ)
  ΓΙΑ Ι ΑΠΟ 1 ΜΕΧΡΙ 10
    ΣΗΜΕΙΟ[Ι] <-- ΨΕΥΔΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΙΑ Ι ΑΠΟ 1 ΜΕΧΡΙ 4
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΑΛΛΟ <-- ΤΥΧΑΙΑ_Τ(1,10)
    ΜΕΧΡΙΣ_ΟΤΟΥ ΟΧΙ ΣΗΜΕΙΟ[ΑΛΛΟ]
    ΣΗΜΕΙΟ[ΑΛΛΟ] <-- ΑΛΗΘΗΣ
    ΠΑΙΧΝΙΔΙ[Ι] <-- ΑΛΛΟ-1
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
! ΘΕΛΟΥΜΕ Ο ΠΙΝΑΚΑΣ ΔΟΚΙΜΗ ΝΑ ΕΧΕΙ ΔΙΑΦΟΡΕΤΙΚΑ ΣΗΜΕΙΑ
! ΑΠΟ ΤΟΝ ΠΙΝΑΚΑ ΠΑΙΧΝΙΔΙ.....
  ΓΙΑ Ι ΑΠΟ 1 ΜΕΧΡΙ 4
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΑΛΛΟ <-- ΤΥΧΑΙΑ_Τ(1,10)
    ΜΕΧΡΙΣ_ΟΤΟΥ ΟΧΙ ΣΗΜΕΙΟ[ΑΛΛΟ]
    ΣΗΜΕΙΟ[ΑΛΛΟ] <-- ΑΛΗΘΗΣ
    ΔΟΚΙΜΗ[Ι] <-- ΑΛΛΟ-1
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΡΑΨΕ 'ΒΡΕΣ ΤΑ ΤΕΣΣΕΡΑ ΣΗΜΕΙΑ'
  ΕΝΤΑΞΕΙ <-- ΨΕΥΔΗΣ
  ΣΕΙΡΑ <-- 0
  ΓΡΑΨΕ 'α/α. ΧΧΧΧ [ΕΛΕΓΧΟΣ]'
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΙΑ Ι ΑΠΟ 1 ΜΕΧΡΙ 10
      ΣΗΜΕΙΟ[Ι] <-- ΨΕΥΔΗΣ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΙΑ Ι ΑΠΟ 1 ΜΕΧΡΙ 4
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        ΔΟΚΙΜΗ[Ι] <-- ΕΙΣΑΓΩΓΗ_ΑΚ(ΜΕΤ_Χ[Ι+1]+'ο:',0,9)
      ΜΕΧΡΙΣ_ΟΤΟΥ ΟΧΙ ΣΗΜΕΙΟ[ΔΟΚΙΜΗ[Ι]+1]
      ΣΗΜΕΙΟ[ΔΟΚΙΜΗ[Ι]+1] <-- ΑΛΗΘΗΣ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    ΣΕΙΡΑ <-- ΣΕΙΡΑ+1
    ΑΝ ΣΕΙΡΑ=25 ΤΟΤΕ
      ΤΕΡΜΑΤΙΣΕ <-- ΑΛΗΘΗΣ
    ΤΕΛΟΣ_ΑΝ
    ΓΡΑΜΜΗ[ΣΕΙΡΑ] <-- ΕΛΕΓΧΟΣ('. '+ΜΕΤ_Χ[ΔΟΚΙΜΗ[1]+1]+ΜΕΤ_Χ[ΔΟΚΙΜΗ[2]+1]+ΜΕΤ_Χ[ΔΟΚΙΜΗ[3]+1]+ΜΕΤ_Χ[ΔΟΚΙΜΗ[4]+1]+' [',']')
    ΓΡΑΨΕ 'MASTER MIND'
    ΓΡΑΨΕ '-----------'
    ΓΙΑ Ι ΑΠΟ 1 ΜΕΧΡΙ ΣΕΙΡΑ
      ΓΡΑΨΕ Ι, ΓΡΑΜΜΗ[Ι]
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΜΕΧΡΙΣ_ΟΤΟΥ ΤΕΡΜΑΤΙΣΕ Ή ΕΝΤΑΞΕΙ Ή ΟΧΙ ΝΑΙ('ΘΕΣ ΝΑ ΣΥΝΕΧΙΣΕΙΣ')
  ΑΝ ΟΧΙ ΕΝΤΑΞΕΙ ΤΟΤΕ
    ΓΙΑ Ι ΑΠΟ 1 ΜΕΧΡΙ 4
      ΔΟΚΙΜΗ[Ι] <-- ΠΑΙΧΝΙΔΙ[Ι]
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    ΛΥΣΗ <-- ΕΛΕΓΧΟΣ('ΛΥΣΗ '+ΜΕΤ_Χ[ΔΟΚΙΜΗ[1]+1]+ΜΕΤ_Χ[ΔΟΚΙΜΗ[2]+1]+ΜΕΤ_Χ[ΔΟΚΙΜΗ[3]+1]+ΜΕΤ_Χ[ΔΟΚΙΜΗ[4]+1]+' [',']')
    ΓΡΑΨΕ ΛΥΣΗ
  ΑΛΛΙΩΣ
    ΓΡΑΨΕ 'ΜΠΡΑΒΩ ΤΟ ΒΡΗΚΕΣ'
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ

ΣΥΝΑΡΤΗΣΗ ΤΥΧΑΙΑ_Τ(ΑΠ, ΕΩΣ):ΑΚΕΡΑΙΑ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: ΑΠ, ΕΩΣ
ΑΡΧΗ
  Ν <-- N + Α DIV 123
  Α <-- Ν + Α MOD 113031
  Ν <-- (Ν MOD 100)*100+(N DIV 100) MOD 100
  ΑΝ ΑΠ<>ΕΩΣ ΤΟΤΕ
    ΤΥΧΑΙΑ_Τ <-- (Ν MOD (ΕΩΣ-ΑΠ+1))+ΑΠ
  ΑΛΛΙΩΣ
    ΤΥΧΑΙΑ_Τ <-- ΑΠ
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ

ΣΥΝΑΡΤΗΣΗ ΝΑΙ(ΕΜΦΑΝΙΣΗ) :ΛΟΓΙΚΗ
ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ: ΕΜΦΑΝΙΣΗ, ΝΝ
  ΛΟΓΙΚΕΣ: ΟΚ
ΑΡΧΗ
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΡΑΨΕ ΕΜΦΑΝΙΣΗ,'(Ν/Ο)'
    ΔΙΑΒΑΣΕ ΝΝ
    ΟΚ <-- ΨΕΥΔΗΣ
    ΑΝ (ΝΝ='N') Ή (ΝΝ='Ν') ΤΟΤΕ
      ΝΑΙ <-- ΑΛΗΘΗΣ
      ΟΚ <-- ΑΛΗΘΗΣ
    ΑΛΛΙΩΣ_ΑΝ (ΝΝ='O') Ή (ΝΝ='Ο') ΤΟΤΕ
      ΝΑΙ <-- ΨΕΥΔΗΣ
      ΟΚ <-- ΑΛΗΘΗΣ
    ΤΕΛΟΣ_ΑΝ
  ΜΕΧΡΙΣ_ΟΤΟΥ ΟΚ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ


ΣΥΝΑΡΤΗΣΗ ΕΙΣΑΓΩΓΗ_ΑΚ(ΕΜΦΑΝΙΣΗ, ΚΑΤΩ_ΟΡΙΟ, ΠΑΝΩ_ΟΡΙΟ) :ΑΚΕΡΑΙΑ

ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ: ΕΜΦΑΝΙΣΗ
  ΑΚΕΡΑΙΕΣ: ΚΑΤΩ_ΟΡΙΟ, ΠΑΝΩ_ΟΡΙΟ, ΑΡΧΙΚΗ
ΑΡΧΗ
  ΑΡΧΙΚΗ <-- ΚΑΤΩ_ΟΡΙΟ-1
  ΟΣΟ (ΑΡΧΙΚΗ<ΚΑΤΩ_ΟΡΙΟ) Ή (ΑΡΧΙΚΗ>ΠΑΝΩ_ΟΡΙΟ) ΕΠΑΝΑΛΑΒΕ
    ΓΡΑΨΕ ΕΜΦΑΝΙΣΗ
    ΔΙΑΒΑΣΕ ΑΡΧΙΚΗ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΕΙΣΑΓΩΓΗ_ΑΚ <-- ΑΡΧΙΚΗ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ

ΣΥΝΑΡΤΗΣΗ ΕΛΕΓΧΟΣ(ΑΡΧΙΚΟ, ΤΕΛΙΚΟ ):ΧΑΡΑΚΤΗΡΕΣ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: Κ,Λ, ΣΩΣΤΟ, ΥΠΑΡΧΕΙ
  ΧΑΡΑΚΤΗΡΕΣ: ΑΠΑΝΤΗΣΗ, ΑΡΧΙΚΟ,ΤΕΛΙΚΟ
ΑΡΧΗ
! ΕΛΕΓΧΟΣ 4Χ4
  ΥΠΑΡΧΕΙ <-- 0
  ΣΩΣΤΟ <-- 0
  ΑΠΑΝΤΗΣΗ <-- ''
  ΓΙΑ Κ ΑΠΟ 1 ΜΕΧΡΙ 4
    ΑΝ ΠΑΙΧΝΙΔΙ[Κ]=ΔΟΚΙΜΗ[Κ] ΤΟΤΕ
      ΣΩΣΤΟ <-- ΣΩΣΤΟ+1
    ΑΛΛΙΩΣ
      ΓΙΑ Λ ΑΠΟ 1 ΜΕΧΡΙ 4
        ΑΝ ΠΑΙΧΝΙΔΙ[Κ]=ΔΟΚΙΜΗ[Λ] ΤΟΤΕ
          ΥΠΑΡΧΕΙ <-- ΥΠΑΡΧΕΙ+1
        ΤΕΛΟΣ_ΑΝ
      ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΑΝ ΣΩΣΤΟ=4 ΤΟΤΕ
    ΕΝΤΑΞΕΙ <-- ΑΛΗΘΕΣ
  ΤΕΛΟΣ_ΑΝ

! ΑΝΑΚΑΤΕΜΑ ΑΠΑΝΤΗΣΗΣ
  ΟΣΟ (ΥΠΑΡΧΕΙ+ΣΩΣΤΟ)>0 ΕΠΑΝΑΛΑΒΕ
    ΑΝ ΤΥΧΑΙΑ_Τ(1,20)>10 ΤΟΤΕ
      ΑΝ ΣΩΣΤΟ>0 ΤΟΤΕ
        ΣΩΣΤΟ <-- ΣΩΣΤΟ-1
        ΑΠΑΝΤΗΣΗ <-- ΑΠΑΝΤΗΣΗ+'*'
      ΤΕΛΟΣ_ΑΝ
    ΑΛΛΙΩΣ
      ΑΝ ΥΠΑΡΧΕΙ>0 ΤΟΤΕ
        ΥΠΑΡΧΕΙ <-- ΥΠΑΡΧΕΙ-1
        ΑΠΑΝΤΗΣΗ <-- ΑΠΑΝΤΗΣΗ+'%'
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΕΛΕΓΧΟΣ <-- ΑΡΧΙΚΟ+ΑΠΑΝΤΗΣΗ+ΤΕΛΙΚΟ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ

 


ΑΛΛΑΓΗ ΣΤΗΝ ΣΥΝΑΡΤΗΣΗ ΤΥΧΑΙΑ_Τ (πρόσθεσα ένα +1 για να βγαίνει τυχαίος και ίσος με το άνω όριο)

_________________
Γλώσσα προγραμματισμού M2000


Κορυφή
 Προφίλ  
Απάντηση με παράθεση  
 Θέμα δημοσίευσης:
ΔημοσίευσηΔημοσιεύτηκε: Παρ 16 Δεκ 2005 05:58 am 
ΜΕΧΡΙΣ_ΟΤΟΥ ΟΧΙ ΣΗΜΕΙΟ[ΑΛΛΟ] -> Γραμμή 41 - Αναμενόταν "]"


koitakseto ligo kalutera :) kali douleia anyway


Κορυφή
  
Απάντηση με παράθεση  
 Θέμα δημοσίευσης:
ΔημοσίευσηΔημοσιεύτηκε: Παρ 16 Δεκ 2005 09:03 pm 
Χωρίς σύνδεση
Διαχειριστής

Εγγραφή: Παρ 28 Φεβ 2003 06:10 pm
Δημοσιεύσεις: 84
Φίλε επισκέπτη, το πρόγραμμα του bugman λειτουργούσε κανονικά όταν το δημοσίευσε.
Το σφάλμα εμφανίζεται στην έκδοση 8.1 στην οποία έγινε προαιρετική η χρήση παρενθέσεων στις εκφράσεις που έχουν λογικούς τελεστές.
Συγκεκριμένα, το λάθος εμφανίζεται όταν επενεργεί η ΟΧΙ σε στοιχείο πίνακα.
Το bug έχει ήδη διορθωθεί, έτσι αυτό το πρόβλημα δεν θα υπάρχει στην επόμενη έκδοση της ΓλωσσοΜάθειας (8.2).
Μέχρι τότε, αρκεί να γίνει η διόρθωση

ΜΕΧΡΙΣ_ΟΤΟΥ ΟΧΙ ( ... )

δηλαδή να προστεθούν παρενθέσεις στις ΜΕΧΡΙΣ_ΟΤΟΥ.


Κορυφή
 Προφίλ  
Απάντηση με παράθεση  
 Θέμα δημοσίευσης: Re: ΠΑΙΧΝΙΔΙ ΤΥΠΟΥ MASTER MIND
ΔημοσίευσηΔημοσιεύτηκε: Παρ 17 Νοέμ 2017 05:28 pm 
Χωρίς σύνδεση

Εγγραφή: Πέμ 01 Μάιος 2003 10:25 pm
Δημοσιεύσεις: 38
Τοποθεσία: Καλλιθέα Αττικής
Μια ματιά έριξα και βρήκα ένα bug....ως bugman.
προφανώς στην μεταγραφή του προγράμματος, έχει γίνει αλλαγή στην μεταβλητή:
πχ εδώ δείτε ότι το N αριστερά δεν είναι το ίδιο με το N δεξιά, το πρώτο είναι το ελληνικό ενώ το δεύτερο το αγγλικό!

Ν <-- N + Α DIV 123

_________________
Γλώσσα προγραμματισμού M2000


Κορυφή
 Προφίλ  
Απάντηση με παράθεση  
Τελευταίες δημοσιεύσεις:  Ταξινόμηση ανά  
Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 4 Δημοσιεύσεις ] 

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]


Μέλη σε σύνδεση

Μέλη σε αυτή την Δ. Συζήτηση: Δεν υπάρχουν εγγεγραμμένα μέλη και 17 επισκέπτες


Δεν μπορείτε να δημοσιεύετε νέα θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να απαντάτε σε θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επεξεργάζεστε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να διαγράφετε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επισυνάπτετε αρχεία σε αυτή τη Δ. Συζήτηση

Αναζήτηση για:
Μετάβαση σε:  
cron
Προβολές: