Τώρα είναι Πέμ 28 Μαρ 2024 06:18 pm

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]




Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 3 Δημοσιεύσεις ] 
Συγγραφέας Μήνυμα
ΔημοσίευσηΔημοσιεύτηκε: Παρ 17 Δεκ 2004 03:14 pm 
Χωρίς σύνδεση

Εγγραφή: Πέμ 22 Απρ 2004 11:16 am
Δημοσιεύσεις: 60
Τοποθεσία: Θεσσαλονίκη
Το επόμενο ζήτημα αποτελεί ΘΕΜΑ Α' ΦΑΣΗΣ του 17ου Πανελλήνιου Διαγωνισμού Πληροφορικής.
Πληροφορίες θα πάρετε από το δικτυακό τόπο http://www.pdp.gr/
Παρακαλείστε ιδιαίτερα να μην δημοσιεύσετε τις απαντήσεις σας στο Ασκησιολόγιο της Γλωσσομάθειας
μέχρι τις 10 Ιανουρίου 2005, όπου λήγει η Α΄ φάση του Π.Δ.Π.
Εώς τότε προσπαθήστε με την ησυχία σας. Το θέμα (απρόσμενα εύκολο) θυμίζει αρκετά τα υποερωτήματα δ και ε
του 4ου ζητήματος των Πανελαδικών Εξετάσεων στο μάθημα ΑΕΠΠ Ιουνιού 2004.

Syntax: [ Download ] [ Hide ]

!
! **********************************  Δέκαθλο  *****************************************************************
! Ένα από τα πλέον όμορφα και ταυτόχρονα δυναμικά Ολυμπιακά Αγωνίσματα είναι το Δέκαθλο.
! Οι δεκαθλητές, δοκιμάζονται κυριολεκτικά σε δέκα αγωνίσματα στίβου.
! Στους Ολυμπιακούς Αγώνες της Αθήνας οι δεκαθλητές αγωνίστηκαν σε αυτά τα αγωνίσματα, στις 23 & 24 Αυγούστου 2004.
! Η τελική κατάταξη προέκυψε από το άθροισμα των βαθμών που συγκέντρωσαν οι αθλητές σε κάθε αγώνισμα.
! Για λόγους καθαρά στατιστικής, σε κάθε αγώνισμα βγήκε ένας «νικητής» αγωνίσματος.
! Στο άλμα επί κοντώ, ο νικητής προκύπτει από τους αθλητές που υπερπήδησαν το ίδιο ύψος
! με μικρότερο αριθμό συνολικών προσπαθειών.
! Αθλητές με ίδιο αριθμό προσπαθειών που υπερπήδησαν το ίδιο μέγιστο ύψος ανακηρύσσονται εξ ίσου νικητές.
!
! Να γραφεί πρόγραμμα το οποίο θα δέχεται για είσοδο τον αριθμό των αξιολογούμενων αθλητών (Ν),
! με βάση τη σειρά συμμετοχής στο άθλημα και για κάθε αθλητή,
! Στη συνέχεια θα πρέπει να δέχεται το τελικό ύψος (Υ) υπερπήδησης σε cm
! και τον αριθμό των συνολικών προσπαθειών (Π) για κάθε αθλητή.
! Το πρόγραμμα θα επιστρέφει τον αριθμό των νικητών του αγωνίσματος και στη συνέχεια τη σειρά συμμετοχής,
! που αυτός / αυτοί είχε / είχαν.
!
! *** Περιορισμοί: ****
! Οι αθλητές  πρέπει να είναι:   1<Ν<=128,                                (ακέραια ποσότητα)
! Το ύψος θα διαβάζεται σε cm :  400<=Υ<=650 (0: οι άκυρες προσπάθειες)   (ακέραια ποσότητα)
! Το σύνολο των προσπαθειών είναι:, 3<=Π<=30.                             (ακέραια ποσότητα)
!
! ******** ΠΑΡΑΔΕΙΓΜΑ 1 *************
! Για παράδειγμα αν διαβάστηκε πλήθος αθλητών Ν=10 και ακολουθως τα Υψη και οι προσπάθεις όπως παρακάτω:
!α/α  Υ    Π
! 1  590   9
! 2  595  12
! 3  585   6
! 4  575   9
! 5  595   9
! 6  590  12
! 7  585   6
! 8  590  12
! 9  585   9
! 10   0   3
!
! Τοτε τα αποτελεσμάτα πρέπει να ειναι:  πλήθος νικητών=1, Νικητής είναι ο αθλητής 5.
!
!
! ******** ΠΑΡΑΔΕΙΓΜΑ 2 *************
! Για παράδειγμα αν διαβάστηκε πλήθος αθλητών Ν=8 και ακολουθως τα Υψη και οι προσπάθεις όπως παρακάτω:
!α/α  Υ    Π
! 1  570   9
! 2    0   3
! 3  585   6
! 4  575   9
! 5  575   9
! 6  585   6
! 7  570  12
! 8  585   9
!
! Τοτε τα αποτελεσμάτα πρέπει να ειναι:  πλήθος νικητών=2, Νικητές είναι οι αθλητής 3 και 6.

 


Τελευταία επεξεργασία από kfrei και Σάβ 25 Νοέμ 2006 02:34 am, έχει επεξεργασθεί 3 φορά/ες συνολικά

Κορυφή
 Προφίλ  
Απάντηση με παράθεση  
 Θέμα δημοσίευσης:
ΔημοσίευσηΔημοσιεύτηκε: Κυρ 16 Ιαν 2005 08:13 pm 
Χωρίς σύνδεση

Εγγραφή: Πέμ 22 Απρ 2004 11:16 am
Δημοσιεύσεις: 60
Τοποθεσία: Θεσσαλονίκη
Παραθέτω στη συνέχεια ορισμένες λύσεις μαθητών :wink:

Νίκος Βασίλας, Θεσσαλονίκη

Syntax: [ Download ] [ Hide ]
ΠΡΟΓΡΑΜΜΑ ΔΕΚΑΘΛΟ
ΣΤΑΘΕΡΕΣ
  S=128
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: max,min,w,n,i,y[S],p[S],a[S]
ΑΡΧΗ

  ΔΙΑΒΑΣΕ n
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ n
    ΔΙΑΒΑΣΕ y[i],p[i]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  max <-- y[1]
  min <-- p[1]
  ΓΙΑ i ΑΠΟ 2 ΜΕΧΡΙ n
    ΑΝ y[i]>max ΤΟΤΕ
      max <-- y[i]
      min <-- p[i]
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ n
    ΑΝ (y[i]=max) ΚΑΙ (p[i]<=min) ΤΟΤΕ
      min <-- p[i]
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  w <-- 0
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ n
    ΑΝ (y[i]=max) ΚΑΙ (p[i]=min) ΤΟΤΕ
      w <-- w+1
      a[w] <-- i
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΡΑΨΕ 'πλήθος νικητών=',w,' και είναι οι '

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ w
    ΓΡΑΨΕ a[i]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ

 


Αν Ν το πλήθος των αθλητών και w το πλήθος των νικητών,
τότε το παραπάνω προγραμμα εκτελεί: 4*Ν + w επαναλήψεις
------------------------------------------------------------------------------

Νίκος Μυλωνάς, Θεσσαλονίκη, Μακρίδης Ελευθέριος, Γιαννιτσά

Syntax: [ Download ] [ Hide ]

ΠΡΟΓΡΑΜΜΑ DEKATHLO
ΣΤΑΘΕΡΕΣ
  S=128
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: N,Y[S],P[S],A[S],i,j,temp,NIK
ΑΡΧΗ
  ΔΙΑΒΑΣΕ N

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ N
    ΔΙΑΒΑΣΕ Y[i],P[i]
    A[i] <-- i
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΙΑ i ΑΠΟ 2 ΜΕΧΡΙ N
    ΓΙΑ j ΑΠΟ N ΜΕΧΡΙ i ΜΕ ΒΗΜΑ -1
      ΑΝ Y[j-1]<Y[j] ΤΟΤΕ
        temp <-- Y[j-1]
        Y[j-1] <-- Y[j]
        Y[j] <-- temp
        temp <-- P[j-1]
        P[j-1] <-- P[j]
        P[j] <-- temp
        temp <-- A[j-1]
        A[j-1] <-- A[j]
        A[j] <-- temp
      ΑΛΛΙΩΣ_ΑΝ (Y[j-1]=Y[j])ΚΑΙ (P[j-1]>P[j]) ΤΟΤΕ
        temp <-- P[j-1]
        P[j-1] <-- P[j]
        P[j] <-- temp
        temp <-- A[j-1]
        A[j-1] <-- A[j]
        A[j] <-- temp
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  NIK <-- 0
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ N
    ΑΝ (Y[1]=Y[i]) ΚΑΙ (P[1]=P[i]) ΤΟΤΕ
      NIK <-- NIK+1
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΡΑΨΕ NIK

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ NIK
    ΓΡΑΨΕ A[i]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ

 


Αν Ν το πλήθος των αθλητών, ΝΙΚ το πλήθος των νικητών,
και Τ το πλήθος των επαναλήψεων της ταξινόμησης με Τ=[(1+Ν)/2]*Ν (για την ακρίβεια όπου Ν είναι Ν-1.... άθροισμα όρων αριθμητικής πρόόδου Σ=[(Α1+Αν)/2] *ν )
τότε το παραπάνω προγραμμα εκτελεί: 2*Ν + ΝΙΚ + Τ επαναλήψεις
------------------------------------------------------------------------------


Πετρίδης Λάζαρος, Γιαννιτσά

Syntax: [ Download ] [ Hide ]
ΠΡΟΓΡΑΜΜΑ Δέκαθλο
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:i,Ν,Κ,Ω,Υ[128][128],ΘΕΣΗ[128],Χ,ΤΕΜΠ
  ΛΟΓΙΚΕΣ: shorted
ΑΡΧΗ
  ΔΙΑΒΑΣΕ Ν

  ΓΙΑ Κ ΑΠΟ 1 ΜΕΧΡΙ Ν
    ΔΙΑΒΑΣΕ Υ[Κ][Κ]
    ΘΕΣΗ[Κ] <-- Κ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  i <-- 2
  shorted <-- ψευδής
  ΟΣΟ (i<=Ν) ΚΑΙ (shorted=ψευδής) ΕΠΑΝΑΛΑΒΕ
    shorted <-- αληθής
    ΓΙΑ Ω ΑΠΟ Ν ΜΕΧΡΙ i ΜΕ ΒΗΜΑ -1
      ΑΝ Υ[Ω-1]<Υ[Ω] ΤΟΤΕ
        ΤΕΜΠ <-- Υ[Ω-1]
        Υ[Ω-1] <-- Υ[Ω]
        Υ[Ω] <-- ΤΕΜΠ
        ΤΕΜΠ <-- Π[Ω-1]
        Π[Ω-1] <-- Π[Ω]
        Π[Ω] <-- ΤΕΜΠ
        ΤΕΜΠ <-- ΘΕΣΗ[Ω-1]
        ΘΕΣΗ[Ω-1] <-- ΘΕΣΗ[Ω]
        ΘΕΣΗ[Ω] <-- ΤΕΜΠ
        shorted <-- ψευδής
      ΑΛΛΙΩΣ_ΑΝ (Υ[Ω-1]=Υ[Ω])ΚΑΙ (Π[Ω-1]>Π[Ω]) ΤΟΤΕ
        ΤΕΜΠ <-- Π[Ω-1]
        Π[Ω-1] <-- Π[Ω]
        Π[Ω] <-- ΤΕΜΠ
        ΤΕΜΠ <-- ΘΕΣΗ[Ω-1]
        ΘΕΣΗ[Ω-1] <-- ΘΕΣΗ[Ω]
        ΘΕΣΗ[Ω] <-- ΤΕΜΠ
        shorted <-- ψευδής
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    i <-- i+1
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  Χ <-- 0
  Κ <-- 1
  ΟΣΟ (Υ[1]=Υ[Κ]) ΚΑΙ  (Π[1]=Π[Κ]) ΕΠΑΝΑΛΑΒΕ
    Χ <-- Χ+1
    Κ <-- Κ+1
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΡΑΨΕ Χ
  ΓΙΑ Κ ΑΠΟ 1 ΜΕΧΡΙ Χ
    ΓΡΑΨΕ ΘΕΣΗ[Κ]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ

 


Αν Ν το πλήθος των αθλητών, Χ το πλήθος των νικητών,
και Τ' το πλήθος των επαναλήψεων μιας γρήγορης ταξινόμησης με Τ' στατιστικά αρκετά μικρότερη του Τ =[(1+Ν)/2]*Ν
τότε το παραπάνω προγραμμα εκτελεί: Ν + 2*Χ + Τ' επαναλήψεις
------------------------------------------------------------------------------

Σιταράς Φώτης, Γιαννιτσά

Syntax: [ Download ] [ Hide ]
ΠΡΟΓΡΑΜΜΑ ΔΕΚΑΘΛΟΝ
ΣΤΑΘΕΡΕΣ
  S=128
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: N,i,j,max,min,ΠΛ,Υ[S][S][S]
ΑΡΧΗ
  ΔΙΑΒΑΣΕ N
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ N
    ΔΙΑΒΑΣΕ Υ[i][i]
    Μ[i] <-- 0
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  max <-- Υ[1]
  ΓΙΑ i ΑΠΟ 2 ΜΕΧΡΙ N
    ΑΝ Υ[i]>=max ΤΟΤΕ
      max <-- Υ[i]
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  j <-- 0
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ N
    ΑΝ Υ[i]=max ΤΟΤΕ
      j <-- j+1
      Μ[j] <-- i
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  min <-- Π[Μ[1]]
  ΓΙΑ i ΑΠΟ 2 ΜΕΧΡΙ j
    ΑΝ Π[Μ[i]]<min ΤΟΤΕ  
      min <-- Π[Μ[i]]
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΠΛ <-- 0
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ j
    ΑΝ Π[Μ[i]]=min ΤΟΤΕ
      ΠΛ <-- ΠΛ+1
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΡΑΨΕ ΠΛ            
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ j
    ΑΝ Π[Μ[i]]=min ΤΟΤΕ
      ΓΡΑΨΕ Μ[i]
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ ΔΕΚΑΘΛΟΝ

 


Αν Ν το πλήθος των αθλητών και ΠΛ το πλήθος των νικητών,
και j το πλήθος των "εν δυνάμει νικητών" (με Ν>=j>=ΠΛ) τότε το παραπάνω προγραμμα εκτελεί: 2*Ν +2*j +ΠΛ επαναλήψεις

------------------------------------------------------------------------------

η δική μου .... :wink:

Syntax: [ Download ] [ Hide ]
ΠΡΟΓΡΑΜΜΑ Δέκαθλο
ΣΤΑΘΕΡΕΣ
  size=128
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: Υ[size][size],Α_Α[size],i,j,temp,Ν,NIK
  ΛΟΓΙΚΕΣ: shorted
ΑΡΧΗ
  ΔΙΑΒΑΣΕ Ν

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Ν
    ΔΙΑΒΑΣΕ Υ[i], Π[i]
    Α_Α[i] <-- i
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  i <-- 2
  shorted <-- ψευδής
  ΟΣΟ (i<=Ν) ΚΑΙ (ΟΧΙ shorted) ΕΠΑΝΑΛΑΒΕ
    shorted <-- αληθής
    ΓΙΑ j ΑΠΟ Ν ΜΕΧΡΙ i ΜΕ ΒΗΜΑ -1
      ΑΝ (Υ[j-1]<Υ[j]) Ή ( (Υ[j-1]=Υ[j]) ΚΑΙ (Π[j-1]>Π[j]) ) ΤΟΤΕ
        temp <-- Υ[j-1]
        Υ[j-1] <-- Υ[j]
        Υ[j] <-- temp

        temp <-- Π[j-1]
        Π[j-1] <-- Π[j]
        Π[j] <-- temp

        temp <-- Α_Α[j-1]
        Α_Α[j-1] <-- Α_Α[j]
        Α_Α[j] <-- temp
        shorted <-- ψευδής
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    i <-- i+1
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  NIK <-- 1
  i <-- 2
  ΟΣΟ (Υ[1]=Υ[i]) ΚΑΙ (Π[1]=Π[i]) ΕΠΑΝΑΛΑΒΕ
    i <-- i+1
    NIK <-- NIK+1
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΡΑΨΕ 'πλήθος νικητών=',NIK, '  Νικητές είναι οι αθλητές με α/α:'
  ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ NIK
    ΓΡΑΨΕ Α_Α[j]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ

 

Αν Ν το πλήθος των αθλητών, NIK,το πλήθος των νικητών,
και Τ' το πλήθος των επαναλήψεων μιας γρήγορης ταξινόμησης
τότε το παραπάνω προγραμμα εκτελεί: Ν + 2*NIK + Τ' επαναλήψεις
------------------------------------------------------------------------------
...να και μια ενδιαφέρουσα και πολύ έξυπνη λύση ενός ακόμη μαθητή :lol:

Syntax: [ Download ] [ Hide ]

ΠΡΟΓΡΑΜΜΑ ΔΕΚΑΘΛΟ
ΣΤΑΘΕΡΕΣ
  Size=128
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: max_Y ,min_P,win,y[Size],p[Size],i,N
ΑΡΧΗ
  max_Y  <-- 0
  min_P <-- 0
  win <-- 0
  ΔΙΑΒΑΣΕ N

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ N
    ΔΙΑΒΑΣΕ y[i],p[i]
    ΑΝ (y[i]>max_Y) Ή (y[i]=max_Y) ΚΑΙ (p[i]<min_P) ΤΟΤΕ
      win <-- 1
      max_Y <-- y[i]
      min_P <-- p[i]
    ΑΛΛΙΩΣ_ΑΝ (y[i]=max_Y) ΚΑΙ (p[i]=min_P) ΤΟΤΕ
      win <-- win + 1
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΡΑΨΕ 'πλήθος νικητών=',win ,'  Νικητές είναι οι αθλητές με α/α:'

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ N
    ΑΝ (y[i]=max_Y ) ΚΑΙ (p[i]=min_P) ΤΟΤΕ
      ΓΡΑΨΕ i
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ

 

Αν Ν το πλήθος των αθλητών τότε το παραπάνω προγραμμα εκτελεί: 2*Ν επαναλήψεις !!!!! :wink: [με διαφορά το πιο γρήγορο χρησιμοποιώντας επίσης έναν μονοδιαστατο πίνακα λιγότερο!!!]
------------------------------------------------------------------------------

Τα συμπεράσματα για την ομορφιά του προγραμματισμού, την ταχύτητα εκτέλεσης ενός προγράμματος και τη βέλτιστη λύση ενός προβλήματος, δικά σας..........
------------------------------------------------------------------------------

Σε όλες τις προηγούμενες λύσεις δεν υπήρχαν έλεγχοι καταχώρησης, όπως και βοηθητικά μηνύματα για την εισαγωγή δεδομένων, καθώς για την εισαγωγή δεδομένων χρησιμοποίθηκε η "Αντληση Δεδομένων" από έτοιμα αρχεία κειμένου θεωρώντας τα δεδομένα πάντα έγκυρα.


Ενδεικτικά αρχεία δεδομένων:

ΕΙΣΟΔΟΣ 1

Παράθεση:
10

590 9

595 12

585 6

575 9

595 9

590 12

585 6

590 12

585 9

0 3


ΕΞΟΔΟΣ 1

Παράθεση:
πλήθος νικητών=1 Νικητές είναι οι αθλητές με α/α:
5


-------------------------------------------------------------------------------

ΕΙΣΟΔΟΣ 2

Παράθεση:
8

570 9

0 3

585 6

575 9

575 9

585 6

570 12

585 9


ΕΞΟΔΟΣ 2

Παράθεση:
πλήθος νικητών=2 Νικητές είναι οι αθλητές με α/α:
3
6


-------------------------------------------------------------------------------

_________________
Φρειδερίκος Κώστας
FreiderikosK@hotmail.com


Κορυφή
 Προφίλ  
Απάντηση με παράθεση  
 Θέμα δημοσίευσης:
ΔημοσίευσηΔημοσιεύτηκε: Πέμ 23 Φεβ 2006 02:15 pm 
Χωρίς σύνδεση

Εγγραφή: Πέμ 23 Φεβ 2006 02:12 pm
Δημοσιεύσεις: 2
Ωραία άσκηση. Εύκολη. Πάντος πολύ καλή. :)


Κορυφή
 Προφίλ  
Απάντηση με παράθεση  
Τελευταίες δημοσιεύσεις:  Ταξινόμηση ανά  
Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 3 Δημοσιεύσεις ] 

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]


Μέλη σε σύνδεση

Μέλη σε αυτή την Δ. Συζήτηση: Δεν υπάρχουν εγγεγραμμένα μέλη και 10 επισκέπτες


Δεν μπορείτε να δημοσιεύετε νέα θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να απαντάτε σε θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επεξεργάζεστε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να διαγράφετε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επισυνάπτετε αρχεία σε αυτή τη Δ. Συζήτηση

Αναζήτηση για:
Μετάβαση σε:  
cron
Προβολές: