! ==============================================
! Κάποιο εστιατόριο θέλει να εκτυπώσει έναν
! αλφαβητικό τιμοκατάλογο των φαγητών που
! προσφέρει. Να γίνει πρόγραμμα που να ζητάει
! την ονομασία και την τιμή για 20 φαγητά και
! στη συνέχεια να εμφανίζει αυτά τα στοιχεία
! ταξινομημένα σε αλφαβητική σειρά.
! ==============================================


ΠΡΟΓΡΑΜΜΑ Τιμοκατάλογος_εστιατορίου

ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ: ονόματα[20], βοηθητική_χαρ
  ΑΚΕΡΑΙΕΣ: i, j, τιμές[20], βοηθητική_ακερ

ΑΡΧΗ

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 20
    ΓΡΑΨΕ 'Δώσε το όνομα του ', i, 'ου φαγητού:'
    ΔΙΑΒΑΣΕ ονόματα[i]
    ΓΡΑΨΕ 'Δώσε την τιμή αυτού του φαγητού:'
    ΔΙΑΒΑΣΕ τιμές[i]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΙΑ i ΑΠΟ 2 ΜΕΧΡΙ 20
    ΓΙΑ j ΑΠΟ 20 ΜΕΧΡΙ i ΜΕ ΒΗΜΑ -1
      ΑΝ ονόματα[j-1]>ονόματα[j] ΤΟΤΕ

        βοηθητική_χαρ <-- ονόματα[j-1]
        ονόματα[j-1] <-- ονόματα[j]
        ονόματα[j] <-- βοηθητική_χαρ

        βοηθητική_ακερ <-- τιμές[j-1]
        τιμές[j-1] <-- τιμές[j]
        τιμές[j] <-- βοηθητική_ακερ

      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΡΑΨΕ 'ΑΛΦΑΒΗΤΙΚΟΣ ΤΙΜΟΚΑΤΑΛΟΓΟΣ ΦΑΓΗΤΩΝ'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 20
    ΓΡΑΨΕ  ονόματα[i], '  ', τιμές[i], '  ευρώ'
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ Τιμοκατάλογος_εστιατορίου