Τώρα είναι Πέμ 27 Ιαν 2022 02:05 pm

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]




Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 1 Δημοσίευση ] 
Συγγραφέας Μήνυμα
ΔημοσίευσηΔημοσιεύτηκε: Πέμ 20 Μάιος 2004 10:04 am 
Χωρίς σύνδεση

Εγγραφή: Πέμ 22 Απρ 2004 11:16 am
Δημοσιεύσεις: 60
Τοποθεσία: Θεσσαλονίκη
Παρακάτω ακολουθεί μια σειρά προγραμμάτων που προσεγγίζουν το θέμα της συγχώνευσης μονοδιάστατων ταξινομημέμων πινάκων με διαφορετικούς τρόπους.
Syntax: [ Download ] [ Hide ]
!==========================================================================================================
! Για δύο αστυνομικά τμήματα AΤ1 και AΤ2 τα οποία στελεχώνονται από Ν και Μ αστυνομικούς αντίστοιχα
! ( με 1<=Ν,Μ<15 ) αποθηκεύουμε κατά αύξουσα σειρά τις ηλικίες των αστυνομικών
! σε δύο μονοδιάσταους πίνακες  AΤ1 και AΤ2 αντίστοιχα.
! α) Να αναπτύξετε πρόγραμμα το οποίο αφού διαβάσει το πλήθος των αστυνομικών, και τις ηλικίες τους
!    για κάθε αστυνομικό τμήμα αντίστοιχα, να συγχωνεύει τους δύο αυτούς πίνακες ηλικιών
!    σε έναν επίσης ταξινομημένο πίνακα ΑΤ.
!
!                                 ΠΑΡΑΔΕΙΓΜΑ 1
! ------- ΔΕΔΟΜΕΝΑ --------
! Ν=6   ΑΤ1:  19 23 30 32 36 38        (6 ηλικίες)
! Μ=4   ΑΤ2:  23 25 35 40              (4 ηλικίες)
!
! ---- ΑΠΟΤΕΛΕΣΜΑΤΑ -------
!       ΑΤ:    19 23 23 25 30 32 35 36 38 40      (10 ηλικίες: 6+4)
!
!===========================================================================================================

ΠΡΟΓΡΑΜΜΑ Συγχώνευση_Αστυνομικών_Τμημάτων_α1
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:i,j,Μ,Ν,ΑΤ1[15],ΑΤ2[15],ΑΤ[30],temp
ΑΡΧΗ

  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΡΑΨΕ 'Δώσε πλήθος αστυνομικών του ΑΤ1 (1-15)'
    ΔΙΑΒΑΣΕ Ν
  ΜΕΧΡΙΣ_ΟΤΟΥ (Ν>=1) ΚΑΙ (Ν<=15)

  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΡΑΨΕ 'Δώσε πλήθος αστυνομικών του ΑΤ2 (1-15)'
    ΔΙΑΒΑΣΕ Μ
  ΜΕΧΡΙΣ_ΟΤΟΥ (Μ>=1) ΚΑΙ (Μ<=15)


  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Ν        ! ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ N
    ΑΤ1[i] <-- 2*i+15        !    ΓΡΑΨΕ 'Δώσε την ηλικία του ', i, 'ου αστυνομικού του ΑΤ1'
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ           !    ΔΙΑΒΑΣΕ ΑΤ1[i]
                             ! ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ


  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Μ        ! ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ M
    ΑΤ2[i] <-- 3*i+14        !    ΓΡΑΨΕ 'Δώσε την ηλικία του ', i, 'ου αστυνομικού του ΑΤ2'
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ           !    ΔΙΑΒΑΣΕ ΑΤ2[i]
                             ! ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ


  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Ν
    ΑΤ[i] <-- ΑΤ1[i]        ! To ΑΤ1 (Ν στοιχεία) "περνάει" στην αρχή του ΑΤ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Μ
    ΑΤ[i+Ν] <-- ΑΤ2[i]      ! To ΑΤ2 (Μ στοιχεία) "περνάει" στο τέλος του ΑΤ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΙΑ i ΑΠΟ 2 ΜΕΧΡΙ Ν+Μ     ! το νέο ΑΤ ταξινομείται (Ν+Μ στοιχεία)
    ΓΙΑ j ΑΠΟ Ν+Μ ΜΕΧΡΙ i ΜΕ ΒΗΜΑ -1
      ΑΝ ΑΤ[j-1]>ΑΤ[j] ΤΟΤΕ
        temp <-- ΑΤ[j]
        ΑΤ[j] <-- ΑΤ[j-1]
        ΑΤ[j-1] <-- temp
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΡΑΨΕ                    ! εμφάνιση αποτελεσμάτων
  ΓΡΑΨΕ 'oι ηλικίες του AΤ1 ακολουθούν'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Ν
    ΓΡΑΨΕ_ ΑΤ1[i],' '
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΡΑΨΕ

  ΓΡΑΨΕ
  ΓΡΑΨΕ 'oι ηλικίες του AΤ2 ακολουθούν'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Μ
    ΓΡΑΨΕ_ ΑΤ2[i],' '
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΡΑΨΕ

  ΓΡΑΨΕ
  ΓΡΑΨΕ 'Τo νέο συγχωνευμένο ΑΤ εχεί τις επόμενες ηλικίες'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Μ+Ν
    ΓΡΑΨΕ_ ΑΤ[i],' '
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ
 

Ειναι φανερό ότι ο προηγούμενος αλγόριθμος δεν "εκμεταλεύεται" καθόλου το γεγονός ότι οι δύο αρχικοί πίνακες ΑΤ1 και ΑΤ2 είναι εξ αρχής ταξινομημένοι. Είναι ένας αρκετά αργός αλγόριθμος (αφού απαιτεί Ν+Μ επαναλήψεις + τις επαναλήψεις για ταξινόμηση Ν+Μ στοιχείων), εύκολος όμως στην κατανόηση και την υλοποίηση του. Αντίθετα ο επόμενος αλγόριθμος λειτουργεί σωστά μονο στην περιπτωση που οι δυο αρχικοί πίνακες είναι ταξινομημένοι. Αρκετά πιο γρήγορος (αφού απαιτεί ακριβώς Ν+Μ επαναλήψεις) , αλλά χρειάζεται αρκετή έμπνευση από τον επίδοξο προγραμματιστή-μαθητή.
Syntax: [ Download ] [ Hide ]
!--------------- 2ος Τροπος ------------------------------

ΠΡΟΓΡΑΜΜΑ Συγχώνευση_Αστυνομικών_Τμημάτων_α2
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:i,j,k,Μ,Ν,p,ΑΤ1[15],ΑΤ2[15],ΑΤ[30],temp
ΑΡΧΗ

  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΡΑΨΕ 'Δώσε πλήθος αστυνομικών του ΑΤ1 (1-15)'
    ΔΙΑΒΑΣΕ Ν
  ΜΕΧΡΙΣ_ΟΤΟΥ (Ν>=1) ΚΑΙ (Ν<=15)

  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΡΑΨΕ 'Δώσε πλήθος αστυνομικών του ΑΤ2 (1-15)'
    ΔΙΑΒΑΣΕ Μ
  ΜΕΧΡΙΣ_ΟΤΟΥ (Μ>=1) ΚΑΙ (Μ<=15)


  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Ν        ! ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ N
    ΑΤ1[i] <-- 2*i+15        !    ΓΡΑΨΕ 'Δώσε την ηλικία του ', i, 'ου αστυνομικού του ΑΤ1'
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ           !    ΔΙΑΒΑΣΕ ΑΤ1[i]
                             ! ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ


  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Μ        ! ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ M
    ΑΤ2[i] <-- 3*i+14        !    ΓΡΑΨΕ 'Δώσε την ηλικία του ', i, 'ου αστυνομικού του ΑΤ2'
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ           !    ΔΙΑΒΑΣΕ ΑΤ2[i]
                             ! ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  i <-- 1
  j <-- 1
  k <-- 1

  ΟΣΟ (i<=Ν) ΚΑΙ (j<=Μ) ΕΠΑΝΑΛΑΒΕ
    ΑΝ ΑΤ1[i]<ΑΤ2[j] ΤΟΤΕ
      ΑΤ[k] <-- ΑΤ1[i]
      i <-- i+1
    ΑΛΛΙΩΣ
      ΑΤ[k] <-- ΑΤ2[j]
      j <-- j+1
    ΤΕΛΟΣ_ΑΝ
    k <-- k+1
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΑΝ i>Ν ΤΟΤΕ
    ΓΙΑ p ΑΠΟ j ΜΕΧΡΙ Μ
      ΑΤ[k] <-- ΑΤ2[p]
      k <-- k+1
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΑΛΛΙΩΣ
    ΓΙΑ p ΑΠΟ i ΜΕΧΡΙ Ν
      ΑΤ[k] <-- ΑΤ1[p]
      k <-- k+1
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΑΝ

  ΓΡΑΨΕ                    ! εμφάνιση αποτελεσμάτων
  ΓΡΑΨΕ 'oι ηλικίες του AΤ1 ακολουθούν'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Ν
    ΓΡΑΨΕ_ ΑΤ1[i],' '
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΡΑΨΕ

  ΓΡΑΨΕ
  ΓΡΑΨΕ 'oι ηλικίες του AΤ2 ακολουθούν'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Μ
    ΓΡΑΨΕ_ ΑΤ2[i],' '
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΡΑΨΕ

  ΓΡΑΨΕ
  ΓΡΑΨΕ 'Τo νέο συγχωνευμένο ΑΤ εχεί τις επόμενες ηλικίες'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Μ+Ν
    ΓΡΑΨΕ_ ΑΤ[i],' '
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ

 


Αφού τα καταφέραμε μεχρι εδώ ....... ενδιαφέρον έχει η επόμενη αρκετά πιο απαιτητική παραλλαγή.

Syntax: [ Download ] [ Hide ]
!==========================================================================================================
! β) Να τροποποιήσετε το παραπάνω πρόγραμμα έτσι ώστε κατά τη συγχώνευση κάθε ηλικία να παρουσιάζεται
!     μόνο μία φορά στο νέο ταξινομημένο πίνακα ΑΤ.
!
!                                 ΠΑΡΑΔΕΙΓΜΑ 2
! ------- ΔΕΔΟΜΕΝΑ --------
! Ν=8   ΑΤ1:  19 19 30 32 36 38 40 41     (8 ηλικίες)
! Μ=6   ΑΤ2:  20 21 32 35 39 40           (6 ηλικίες)
!
! ----- ΑΠΟΤΕΛΕΣΜΑΤΑ -------
!       ΑΤ:    19 20 21 30 32 35 36 38 39 40 41  (11 ηλικίες αφού βρέθηκαν 3 όμοιες: 19, 32 & 40)
!
!===========================================================================================================

!--------------- 1ος Τροπος ------------------------------

ΠΡΟΓΡΑΜΜΑ Συγχώνευση_Αστυνομικών_Τμημάτων_β1
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:i,j,k,Μ,Ν,p,ΑΤ1[15],ΑΤ2[15],ΑΤ[30],temp,όμοια
ΑΡΧΗ

  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΡΑΨΕ 'Δώσε πλήθος αστυνομικών του ΑΤ1 (1-15)'
    ΔΙΑΒΑΣΕ Ν
  ΜΕΧΡΙΣ_ΟΤΟΥ (Ν>=1) ΚΑΙ (Ν<=15)

  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΡΑΨΕ 'Δώσε πλήθος αστυνομικών του ΑΤ2 (1-15)'
    ΔΙΑΒΑΣΕ Μ
  ΜΕΧΡΙΣ_ΟΤΟΥ (Μ>=1) ΚΑΙ (Μ<=15)


  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Ν        ! ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ N
    ΑΤ1[i] <-- 2*i+15        !    ΓΡΑΨΕ 'Δώσε την ηλικία του ', i, 'ου αστυνομικού του ΑΤ1'
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ           !    ΔΙΑΒΑΣΕ ΑΤ1[i]
                             ! ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ


  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Μ        ! ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ M
    ΑΤ2[i] <-- 3*i+14        !    ΓΡΑΨΕ 'Δώσε την ηλικία του ', i, 'ου αστυνομικού του ΑΤ2'
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ           !    ΔΙΑΒΑΣΕ ΑΤ2[i]
                             ! ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ


  ΑΝ ΑΤ1[1]<ΑΤ2[1] ΤΟΤΕ
    ΑΤ[1] <-- ΑΤ1[1]
    i <-- 2
    j <-- 1
  ΑΛΛΙΩΣ
    ΑΤ[1] <-- ΑΤ2[1]
    i <-- 1
    j <-- 2
  ΤΕΛΟΣ_ΑΝ

  k <-- 2
  όμοια <-- 0

  ΟΣΟ (i<=Ν) ΚΑΙ (j<=Μ) ΕΠΑΝΑΛΑΒΕ
    ΑΝ ΑΤ1[i]<ΑΤ2[j] ΤΟΤΕ
      ΑΝ ΑΤ1[i]<>ΑΤ[k-1] ΤΟΤΕ
        ΑΤ[k] <-- ΑΤ1[i]
        k <-- k+1
      ΑΛΛΙΩΣ
        όμοια <-- όμοια+1
      ΤΕΛΟΣ_ΑΝ
      i <-- i+1
    ΑΛΛΙΩΣ
      ΑΝ ΑΤ2[j]<>ΑΤ[k-1] ΤΟΤΕ
        ΑΤ[k] <-- ΑΤ2[j]
        k <-- k+1
      ΑΛΛΙΩΣ
        όμοια <-- όμοια+1
      ΤΕΛΟΣ_ΑΝ
      j <-- j+1
    ΤΕΛΟΣ_ΑΝ

  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΑΝ i>Ν ΤΟΤΕ
    ΓΙΑ p ΑΠΟ j ΜΕΧΡΙ Μ
      ΑΝ ΑΤ2[p]<>ΑΤ[k-1] ΤΟΤΕ
        ΑΤ[k] <-- ΑΤ2[p]
        k <-- k+1
      ΑΛΛΙΩΣ
        όμοια <-- όμοια+1
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΑΛΛΙΩΣ
    ΓΙΑ p ΑΠΟ i ΜΕΧΡΙ Ν
      ΑΝ ΑΤ1[p]<>ΑΤ[k-1] ΤΟΤΕ
        ΑΤ[k] <-- ΑΤ1[p]
        k <-- k+1
      ΑΛΛΙΩΣ
        όμοια <-- όμοια+1
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΑΝ

  ΓΡΑΨΕ                    ! εμφάνιση αποτελεσμάτων
  ΓΡΑΨΕ 'oι ηλικίες του AΤ1 ακολουθούν'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Ν
    ΓΡΑΨΕ_ ΑΤ1[i],' '
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΡΑΨΕ

  ΓΡΑΨΕ
  ΓΡΑΨΕ 'oι ηλικίες του AΤ2 ακολουθούν'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Μ
    ΓΡΑΨΕ_ ΑΤ2[i],' '
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΡΑΨΕ
  ΓΡΑΨΕ

  ΓΡΑΨΕ 'Βρέθηκαν ', όμοια,' όμοιες ηλικίες'
  ΓΡΑΨΕ  ' '

  ΓΡΑΨΕ 'Τo νέο συγχωνευμένο ΑΤ εχεί τις επόμενες ηλικίες'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Μ+Ν-όμοια
    ΓΡΑΨΕ_ ΑΤ[i],' '
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ
 

Ο επόμενος τρόπος είναι αρκετά πιο αργός αφού απαιτεί επιπροσθέτως περισσότερες από (Ν+Μ-ομοια) επαναλήψεις από τον προηγούμενο, και φανερά πιο δύσκολος για να τον ελέγξει κανεις αφού αν και υλοποιείται με την εντολή " ΓΙΑ " ο αριθμός των επαναλήψεων δεν είναι είναι προβλέψιμος εκ των προτέρων. Γενικά παρατείθεται εδώ, γιατί αρκετοί μαθητές τον νιώθουν πιο κοντά στη "λογική" τους , αλλα η εμπειρία δείχνει μαλλον διαφορετική.
Syntax: [ Download ] [ Hide ]
!--------------- 2ος Τροπος ------------------------------

ΠΡΟΓΡΑΜΜΑ Συγχώνευση_Αστυνομικών_Τμημάτων_β2
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:i,j,k,Μ,Ν,p,ΑΤ1[15],ΑΤ2[15],ΑΤ[30],temp,όμοια
ΑΡΧΗ

  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΡΑΨΕ 'Δώσε πλήθος αστυνομικών του ΑΤ1 (1-15)'
    ΔΙΑΒΑΣΕ Ν
  ΜΕΧΡΙΣ_ΟΤΟΥ (Ν>=1) ΚΑΙ (Ν<=15)

  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΡΑΨΕ 'Δώσε πλήθος αστυνομικών του ΑΤ2 (1-15)'
    ΔΙΑΒΑΣΕ Μ
  ΜΕΧΡΙΣ_ΟΤΟΥ (Μ>=1) ΚΑΙ (Μ<=15)


  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Ν        ! ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ N
    ΑΤ1[i] <-- 2*i+15        !    ΓΡΑΨΕ 'Δώσε την ηλικία του ', i, 'ου αστυνομικού του ΑΤ1'
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ           !    ΔΙΑΒΑΣΕ ΑΤ1[i]
                             ! ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ


  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Μ        ! ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ M
    ΑΤ2[i] <-- 3*i+14        !    ΓΡΑΨΕ 'Δώσε την ηλικία του ', i, 'ου αστυνομικού του ΑΤ2'
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ           !    ΔΙΑΒΑΣΕ ΑΤ2[i]
                             ! ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  i <-- 1
  j <-- 1
  k <-- 1

  ΟΣΟ (i<=Ν) ΚΑΙ (j<=Μ) ΕΠΑΝΑΛΑΒΕ
    ΑΝ ΑΤ1[i]<ΑΤ2[j] ΤΟΤΕ
      ΑΤ[k] <-- ΑΤ1[i]
      i <-- i+1
    ΑΛΛΙΩΣ
      ΑΤ[k] <-- ΑΤ2[j]
      j <-- j+1
    ΤΕΛΟΣ_ΑΝ
    k <-- k+1
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΑΝ i>Ν ΤΟΤΕ
    ΓΙΑ p ΑΠΟ j ΜΕΧΡΙ Μ
      ΑΤ[k] <-- ΑΤ2[p]
      k <-- k+1
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΑΛΛΙΩΣ
    ΓΙΑ p ΑΠΟ i ΜΕΧΡΙ Ν
      ΑΤ[k] <-- ΑΤ1[p]
      k <-- k+1
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΑΝ


  όμοια <-- 0
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Μ+Ν-1-όμοια
    ΑΝ ΑΤ[i]=ΑΤ[i+1] ΤΟΤΕ
      ΓΙΑ j ΑΠΟ i ΜΕΧΡΙ Μ+Ν-1-όμοια
        ΑΤ[j] <-- ΑΤ[j+1]
      ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
      όμοια <-- όμοια+1
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΡΑΨΕ 'Βρέθηκαν ', όμοια,' όμοια στοιχεία'
  ΓΡΑΨΕ  ' '


  ΓΡΑΨΕ                    ! εμφάνιση αποτελεσμάτων
  ΓΡΑΨΕ 'oι ηλικίες του AΤ1 ακολουθούν'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Ν
    ΓΡΑΨΕ_ ΑΤ1[i],' '
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΡΑΨΕ

  ΓΡΑΨΕ
  ΓΡΑΨΕ 'oι ηλικίες του AΤ2 ακολουθούν'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Μ
    ΓΡΑΨΕ_ ΑΤ2[i],' '
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΡΑΨΕ
  ΓΡΑΨΕ

  ΓΡΑΨΕ 'Βρέθηκαν ', όμοια,' όμοιες ηλικίες'
  ΓΡΑΨΕ  ' '

  ΓΡΑΨΕ 'Τo νέο συγχωνευμένο ΑΤ εχεί τις επόμενες ηλικίες'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Μ+Ν-όμοια
    ΓΡΑΨΕ_ ΑΤ[i],' '
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ


ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ

 


Κορυφή
 Προφίλ  
Απάντηση με παράθεση  
Τελευταίες δημοσιεύσεις:  Ταξινόμηση ανά  
Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 1 Δημοσίευση ] 

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]


Μέλη σε σύνδεση

Μέλη σε αυτή την Δ. Συζήτηση : Δεν υπάρχουν εγγεγραμμένα μέλη και 1 επισκέπτης


Δεν μπορείτε να δημοσιεύετε νέα θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να απαντάτε σε θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επεξεργάζεστε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να διαγράφετε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επισυνάπτετε αρχεία σε αυτή τη Δ. Συζήτηση

Αναζήτηση για:
Μετάβαση σε:  
Προβολές: