! ==============================================================================
! Μια τράπεζα έχει 100 πελάτες. Να γίνει πρόγραμμα το οποίο:
!   Α) Να ζητάει το ονοματεπώνυμο και το ποσό κατάθεσης του κάθε πελάτη.
!   Β) Να βρίσκει και να εμφανίζει τα ονοματεπώνυμα και τις καταθέσεις των 10
!      καλύτερων πελατών, σε φθίνουσα σειρά.
! ==============================================================================


ΠΡΟΓΡΑΜΜΑ Καταθέσεις_τράπεζας

ΣΤΑΘΕΡΕΣ
  Ν=100
  Κ=10

ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ: ονοματεπώνυμα[Ν], βοηθητική_χαρ
  ΠΡΑΓΜΑΤΙΚΕΣ: καταθέσεις[Ν], βοηθητική_πραγμ
  ΑΚΕΡΑΙΕΣ: i, j

ΑΡΧΗ

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Ν
    ΓΡΑΨΕ 'Δώσε το ονοματεπώνυμο του ', i, 'ου πελάτη:'
    ΔΙΑΒΑΣΕ ονοματεπώνυμα[i]
    ΓΡΑΨΕ 'Δώσε το ποσό κατάθεσης του ', i, 'ου πελάτη:'
    ΔΙΑΒΑΣΕ καταθέσεις[i]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΙΑ i ΑΠΟ 2 ΜΕΧΡΙ Ν
    ΓΙΑ j ΑΠΟ Ν ΜΕΧΡΙ i ΜΕ ΒΗΜΑ -1
      ΑΝ καταθέσεις[j-1]<καταθέσεις[j] ΤΟΤΕ

        βοηθητική_πραγμ <-- καταθέσεις[j]
        καταθέσεις[j] <-- καταθέσεις[j-1]
        καταθέσεις[j-1] <-- βοηθητική_πραγμ

        βοηθητική_χαρ <-- ονοματεπώνυμα[j]
        ονοματεπώνυμα[j] <-- ονοματεπώνυμα[j-1]
        ονοματεπώνυμα[j-1] <-- βοηθητική_χαρ

      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΡΑΨΕ 'Οι καλύτεροι πελάτες είναι οι εξής...'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ Κ
    ΓΡΑΨΕ 'Ονοματεπώνυμο: ', ονοματεπώνυμα[i], '  Κατάθεση: ', καταθέσεις[i]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ Καταθέσεις_τράπεζας