! Σε πίνακα Ομάδες[6] να καταχωρισθούν τα ονόματα 6 ομάδων
! Σε πίνακα Αποτ[6,6] να καταχωρισθούν τα σκορ στους μεταξύ τους
! αγώνες με την μορφή τετραψήφιου ακέραιου που το πρώτο διψήφιο
! τμήμα του είναι οι πόντοι της γηπεδούχου και το δεύτερο οι πόντοι
! της φιλοξενουμένης ομάδας. Στα διαγώνια στοιχεία του πίνακα να
! καταχωρίζεται το μηδέν. Ειναι δεδομένο οτι δεν έχουμε ισοπαλίες.
! Για κάθε νίκη η ομάδα λαμβάνει 1 βαθμό , ενώ στην ήττα 0.
! Να εμφανισθεί η τελική βαθμολογία των ομάδων. ( Ισοβαθμίες; Προς συμπλήρωση)


ΠΡΟΓΡΑΜΜΑ Πρωτάθλημα_Μπάσκετ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: Αποτ[6,6],ι,κ,Βαθμοί[6],Πόντοι_α,Πόντοι_β
  ΧΑΡΑΚΤΗΡΕΣ: Ομάδες[6]
ΑΡΧΗ
! Εισαγωγή ονομάτων των ομάδων στον πίνακα Ομάδες[6]            
  ΓΙΑ ι ΑΠΟ 1 ΜΕΧΡΙ 6
    ΓΡΑΨΕ '   Δώσε την ',ι,'η ομάδα'
    ΔΙΑΒΑΣΕ Ομάδες[ι]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

! Συμπλήρωση του πίνακα Αποτ[6,6]
  ΓΙΑ ι ΑΠΟ 1 ΜΕΧΡΙ 6
    ΓΙΑ κ ΑΠΟ 1 ΜΕΧΡΙ 6
      ΑΝ ι<>κ ΤΟΤΕ
        ΓΡΑΨΕ '   Δώσε το αποτέλεσμα ',Ομάδες[ι],'-',Ομάδες[κ]
        ΔΙΑΒΑΣΕ Αποτ[ι,κ]
      ΑΛΛΙΩΣ
        Αποτ[ι,κ] <-- 0
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

! Μηδενισμός των στοιχείων του πίνακα βαθμών κάθε ομάδας
  ΓΙΑ ι ΑΠΟ 1 ΜΕΧΡΙ 6
    Βαθμοί[ι] <-- 0
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

! Ευρεση των βαθμών κάθε ομάδας και συμπλήρωση του πίνακα βαθμών
  ΓΙΑ ι ΑΠΟ 1 ΜΕΧΡΙ 6
    ΓΙΑ κ ΑΠΟ 1 ΜΕΧΡΙ 6
      ΑΝ ι<>κ ΤΟΤΕ
        Πόντοι_α <-- Αποτ[ι,κ] DIV 100
        Πόντοι_β <-- Αποτ[ι,κ] MOD 100
        ΑΝ Πόντοι_α>Πόντοι_β ΤΟΤΕ
          Βαθμοί[ι] <-- Βαθμοί[ι]+1
        ΑΛΛΙΩΣ
          Βαθμοί[κ] <-- Βαθμοί[κ]+1
        ΤΕΛΟΣ_ΑΝ
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

! Εμφάνιση των ομάδων με τους βαθμούς καθε μιάς.  
  ΓΙΑ ι ΑΠΟ 1 ΜΕΧΡΙ 6
    ΓΡΑΨΕ Ομάδες[ι],Βαθμοί[ι]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ