Ασκησιολόγιο ΓλωσσοΜάθειας
http://spinet.gr/glossomatheia/programs/

Επαναληπτικές Εσπερινό - Θέμα 4
http://spinet.gr/glossomatheia/programs/viewtopic.php?f=39&t=683
Σελίδα 1 από 1

Συγγραφέας:  ΧΑΤΖΗΤΣΟΜΠΑΝΗΣ ΘΕΟΦΙΛΟΣ [ Δευτ 28 Ιούλ 2008 12:50 pm ]
Θέμα δημοσίευσης:  Επαναληπτικές Εσπερινό - Θέμα 4

Syntax: [ Download ] [ Hide ]
! ===================================================================================
! ΕΣΠΕΡΙΝΟ - ΙOYΛIΟΣ 2008 - ΘΕΜΑ 4
! ===================================================================================
! Σε ένα Δήμο υπάρχουν 4 σταθμοί μέτρησης ενός συγκεκριμένου ατμοσφαιρικού ρύπου.
! Η καταγραφή της τιμής του ρύπου γίνεται ανά ώρα και σε 24ωρη βάση. Οι αποδεκτές
! τιμές του ρύπου κυμαίνονται από 0 έως και 100.
! Να γραφεί αλγόριθμος, ο οποίος:
! α. για κάθε σταθμό και για κάθε ώρα του 24ώρου διαβάζει την τιμή του ρύπου και
!    την καταχωρίζει σε πίνακα διαστάσεων 4x24, ελέγχοντας την εγκυρότητα κάθε τιμής.
! β. για κάθε ώρα του 24ώρου υπολογίζει και εμφανίζει τη μέση τιμή του ρύπου από τους
!    4 σταθμούς.
! γ. για κάθε σταθμό βρίσκει και εμφανίζει τη μέγιστη και την ελάχιστη τιμή του ρύπου
!    στο 24ωρο.
! δ. βρίσκει και εμφανίζει τη μέγιστη τιμή του ρύπου στη διάρκεια του 24ώρου, καθώς
!    και την ώρα και τον αριθμό του σταθμού που σημειώθηκε η τιμή αυτή.
!    (Να θεωρήσετε ότι η τιμή αυτή είναι μοναδική στον πίνακα).
! ===================================================================================

ΠΡΟΓΡΑΜΜΑ  ESP_2008_07_4
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ : i , j , st , h
  ΠΡΑΓΜΑΤΙΚΕΣ : x[4,24] , s , mo , min , max
ΑΡΧΗ

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 4
    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 24
      ΓΡΑΨΕ 'Δώσε την τιμή του ρύπου στο σταθμό' , i , 'την ωρα' , j
      ΔΙΑΒΑΣΕ x[i,j]
      ΟΣΟ x[i,j] < 0 ή x[i,j] > 100 ΕΠΑΝΑΛΑΒΕ
        ΓΡΑΨΕ 'Λάθος. Ξαναδώσε'
        ΔΙΑΒΑΣΕ x[i,j]
      ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 24                                      
    s <-- 0
    ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 4
      s <-- s + x[i,j]
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    mo <-- s/24
    ΓΡΑΨΕ 'Μέση τιμή την ώρα' , j ,'=' , mo
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 4
    min <-- x[i,1]
    max <-- x[i,1]
    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 24
      ΑΝ x[i,j] < min ΤΟΤΕ
        min <-- x[i,j]
      ΤΕΛΟΣ_ΑΝ
      ΑΝ x[i,j] > max ΤΟΤΕ
        max <-- x[i,j]
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΡΑΨΕ 'Σταθμός Νο:' , i
    ΓΡΑΨΕ 'Ελάχιστη τιμή =' , min
    ΓΡΑΨΕ 'Μέγιστη τιμή =' , max
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  max <-- x[1,1]          ! Θα μπορούσαμε να βάλουμε και το μηδέν
  st <-- 1                ! και τότε δε θα χρειαζόταν να βάλουμε
  h <-- 1                 ! αρχικές τιμές στα st και h
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 4
    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 24
      ΑΝ x[i,j] > max ΤΟΤΕ
        max <-- x[i,j]
        st <-- i
        h <-- j
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΡΑΨΕ 'Η μεγαλύτερη τιμή παρατηρήθηκε στο σταθμό' , st , 'την ώρα' , h

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ
 

Σελίδα 1 από 1 Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]
Powered by phpBB® Forum Software © phpBB Group
http://www.phpbb.com/