Ασκησιολόγιο ΓλωσσοΜάθειας
https://spinet.gr/glossomatheia/programs/

Επαναληπτικές Εσπερινό - Θέμα 3
https://spinet.gr/glossomatheia/programs/viewtopic.php?f=39&t=682
Σελίδα 1 από 1

Συγγραφέας:  ΧΑΤΖΗΤΣΟΜΠΑΝΗΣ ΘΕΟΦΙΛΟΣ [ Δευτ 28 Ιούλ 2008 12:49 pm ]
Θέμα δημοσίευσης:  Επαναληπτικές Εσπερινό - Θέμα 3

Syntax: [ Download ] [ Hide ]
! ==================================================================================
! ΕΣΠΕΡΙΝΟ - ΙOYΛIΟΣ 2008 - ΘΕΜΑ 3
! ==================================================================================
! Μία Νομαρχία διοργάνωσε το 2008 σεμινάριο εθελοντικής δασοπυρόσβεσης, το οποίο
! παρακολούθησαν 500 άτομα. Η Πυροσβεστική Υπηρεσία ζήτησε στοιχεία σχετικά με την
! ηλικία, το φύλο και το μορφωτικό επίπεδο εκπαίδευσης κάθε εθελοντή, προκειμένου
! να εξαγάγει στατιστικά στοιχεία.
! Να γραφεί αλγόριθμος, ο οποίος:
!  α. διαβάζει για κάθε άτομο
!     - το ονοματεπώνυμο,
!     - το έτος γέννησης (χωρίς να απαιτείται έλεγχος εγκυρότητας),
!     - το φύλο, με αποδεκτές τιμές το "Α" για τους άνδρες και
!       το "Γ" για τις γυναίκες,
!     - το μορφωτικό επίπεδο εκπαίδευσης, με αποδεκτές τιμές "Π", "Δ" ή "Τ",
!       που αντιστοιχούν σε Πρωτοβάθμια, Δευτεροβάθμια ή Τριτοβάθμια Εκπαίδευση,
!       και τα καταχωρίζει σε κατάλληλους μονοδιάστατους πίνακες.
!  β. υπολογίζει και εμφανίζει το πλήθος των ατόμων με ηλικία μικρότερη των 30 ετών.
!  γ. υπολογίζει και εμφανίζει το ποσοστό των γυναικών με επίπεδο Τριτοβάθμιας
!     Εκπαίδευσης στο σύνολο των εθελοντριών.
!  δ. εμφανίζει τα ονόματα των ατόμων με τη μεγαλύτερη ηλικία.
! ==================================================================================

ΠΡΟΓΡΑΜΜΑ  ESP_2008_07_3
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ : year[500] , i , n1 , n2 , n3 , min
  ΠΡΑΓΜΑΤΙΚΕΣ : p
  ΧΑΡΑΚΤΗΡΕΣ : name[500] , gender[500] , ed[500]
ΑΡΧΗ

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 500
    ΓΡΑΨΕ 'Δώσε το όνομα του εθελοντή ή της εθελόντριας Νο :' , i
    ΔΙΑΒΑΣΕ name[i]

    ΓΡΑΨΕ 'Δώσε το έτος γέννησης'
    ΔΙΑΒΑΣΕ year[i]

    ΓΡΑΨΕ 'Δώσε το φύλο'
    ΔΙΑΒΑΣΕ gender[i]                                                      
    ΟΣΟ gender[i] <> 'Α' ΚΑΙ gender[i] <> 'Γ' ΕΠΑΝΑΛΑΒΕ
      ΓΡΑΨΕ 'Λάθος. Ξαναδώσε'
      ΔΙΑΒΑΣΕ gender[i]
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

    ΓΡΑΨΕ 'Δώσε το επίπεδο εκπαίδευσης'
    ΔΙΑΒΑΣΕ ed[i]
    ΟΣΟ ed[i] <> 'Π' ΚΑΙ ed[i] <> 'Δ' ΚΑΙ ed[i] <> 'Τ' ΕΠΑΝΑΛΑΒΕ
      ΓΡΑΨΕ 'Λάθος. Ξαναδώσε'
      ΔΙΑΒΑΣΕ ed[i]
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  n1 <-- 0            ! Πλήθος ατόμων με ηλικία < 30
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 500
    ΑΝ 2008 - year[500] < 30 ΤΟΤΕ
      n1 <-- n1 + 1
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΡΑΨΕ 'Πλήθος ατόμων με ηλικία μικρότερη των 30 ετών =' , n1

  n2 <-- 0            ! Πλήθος γυναικών
  n3 <-- 0            ! Γυναίκες τριτοβάθμιας εκπαίδευσης
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 500
    ΑΝ gender[i] = 'Γ' ΤΟΤΕ
      n2 <-- n2 + 1
      ΑΝ ed[i] = 'Τ' ΤΟΤΕ
        n3 <-- n3 + 1
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  p <-- 100*n3/n2
  ΓΡΑΨΕ 'Ποσοστό των γυναικών με επίπεδο Τριτοβάθμιας Εκπαίδευσης στο σύνολο των εθελοντριών =' , p

  min <-- year[1]      ! Τα άτομα με τη μεγαλύτερη ηλικία έχουν το μικρότερο έτος γέννησης.
  ΓΙΑ i ΑΠΟ 2 ΜΕΧΡΙ 500
    ΑΝ year[i] < min ΤΟΤΕ
      min <-- year[i]
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΡΑΨΕ 'Τα μεγαλύτερα σε ηλικία άτομα είναι τα εξής:'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 500
    ΑΝ year[i] = min ΤΟΤΕ
      ΓΡΑΨΕ name[i]
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ
 

Σελίδα 1 από 1 Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]
Powered by phpBB® Forum Software © phpBB Group
http://www.phpbb.com/