Ασκησιολόγιο ΓλωσσοΜάθειας
https://spinet.gr/glossomatheia/programs/

Ημερήσιο - Θέμα 3
https://spinet.gr/glossomatheia/programs/viewtopic.php?f=39&t=669
Σελίδα 1 από 1

Συγγραφέας:  ΧΑΤΖΗΤΣΟΜΠΑΝΗΣ ΘΕΟΦΙΛΟΣ [ Δευτ 28 Ιούλ 2008 12:34 pm ]
Θέμα δημοσίευσης:  Ημερήσιο - Θέμα 3

Syntax: [ Download ] [ Hide ]
! ===============================================================================================
! ΗΜΕΡΗΣΙΟ - ΙOYNIΟΣ 2008 - ΘΕΜΑ 3
! ===============================================================================================
! Μία εταιρεία ενοικίασης αυτοκινήτων έχει νοικιάσει 30 αυτοκίνητα τα οποία κατηγοριοποιούνται
! σε οικολογικά και συμβατικά. Η πολιτική χρέωσης για την ενοικίαση ανά κατηγορία και ανά ημέρα
! δίνεται στον παρακάτω πίνακα.
!              ---------------------------------------------------
!                  ΗΜΕΡΕΣ        ΟΙΚΟΛΟΓΙΚΑ        ΣΥΜΒΑΤΙΚΑ
!              ---------------------------------------------------
!                   1 - 7        30 € ανά ημέρα    40 € ανά ημέρα
!                   8 - 16       20 € ανά ημέρα    30 € ανά ημέρα
!               από 17 και άνω   10 € ανά ημέρα    20 € ανά ημέρα
!              ---------------------------------------------------
!  1. Να αναπτύξετε πρόγραμμα το οποίο:
!     α. Περιλαμβάνει τμήμα δηλώσεων μεταβλητών.
!     β. Για κάθε αυτοκίνητο το οποίο έχει ενοικιαστεί:
!        i. Διαβάζει την κατηγορία του ("ΟΙΚΟΛΟΓΙΚΑ" ή "ΣΥΜΒΑΤΙΚΑ") και τις ημέρες ενοικίασης.
!       ii. Καλεί υποπρόγραμμα με είσοδο την κατηγορία του αυτοκινήτου και τις ημέρες ενοικίασης
!           και υπολογίζει με βάση τον παραπάνω πίνακα τη χρέωση.
!      iii. Εμφανίζει το μήνυμα "χρέωση" και τη χρέωση που υπολογίσατε.
!    γ. Υπολογίζει και εμφανίζει το πλήθος των οικολογικών και των συμβατικών αυτοκινήτων.
!
! 2. Να κατασκευάσετε το κατάλληλο υποπρόγραμμα του ερωτήματος 1.β.ii .
!
! ΣΗΜΕΙΩΣΗ: 1) Δεν απαιτείται έλεγχος εγκυρότητας για τα δεδομένα εισόδου και
!           2) Ο υπολογισμός της χρέωσης δεν πρέπει να γίνει κλιμακωτά.
! ===============================================================================================
!
ΠΡΟΓΡΑΜΜΑ ΗΜ_2008_06_3
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ : d , i , x , n1 , n2
  ΧΑΡΑΚΤΗΡΕΣ : cat
ΑΡΧΗ

  n1 <-- 0             ! ΠΛΗΘΟΣ ΟΙΚΟΛΟΓΙΚΩΝ ΑΥΤΟΚΙΝΗΤΩΝ
  n2 <-- 0             ! ΠΛΗΘΟΣ ΣΥΜΒΑΤΙΚΩΝ ΑΥΤΟΚΙΝΗΤΩΝ

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 30

    ΓΡΑΨΕ 'Δώσε την κατηγορία του αυτοκινήτου Νο' , i
    ΔΙΑΒΑΣΕ cat
    ΓΡΑΨΕ 'Πόσες ημέρες νοικιάστηκε ;'
    ΔΙΑΒΑΣΕ d

    ΑΝ cat = 'ΟΙΚΟΛΟΓΙΚΟ' ΤΟΤΕ
      n1 <-- n1 + 1
    ΑΛΛΙΩΣ
      n2 <-- n2 + 1
    ΤΕΛΟΣ_ΑΝ                                                                                            

    x <-- poso(cat , d)
    ΓΡΑΨΕ 'ΧΡΕΩΣΗ =' , x

  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΡΑΨΕ 'ΠΛΗΘΟΣ ΟΙΚΟΛΟΓΙΚΩΝ ΑΥΤΟΚΙΝΗΤΩΝ =' , n1
  ΓΡΑΨΕ 'ΠΛΗΘΟΣ ΣΥΜΒΑΤΙΚΩΝ ΑΥΤΟΚΙΝΗΤΩΝ  =' , n2

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ


ΣΥΝΑΡΤΗΣΗ poso(c , x) : ΑΚΕΡΑΙΑ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ : x
  ΧΑΡΑΚΤΗΡΕΣ : c
ΑΡΧΗ
  ΑΝ x <= 7 ΤΟΤΕ
    ΑΝ c = 'ΟΙΚΟΛΟΓΙΚΟ' ΤΟΤΕ
      poso <-- x*30
    ΑΛΛΙΩΣ
      poso <-- x*40
    ΤΕΛΟΣ_ΑΝ
  ΑΛΛΙΩΣ_ΑΝ x <= 16 ΤΟΤΕ
    ΑΝ c = 'ΟΙΚΟΛΟΓΙΚΟ' ΤΟΤΕ
      poso <-- x*20
    ΑΛΛΙΩΣ
      poso <-- x*30
    ΤΕΛΟΣ_ΑΝ
  ΑΛΛΙΩΣ
    ΑΝ c = 'ΟΙΚΟΛΟΓΙΚΟ' ΤΟΤΕ
      poso <-- x*10
    ΑΛΛΙΩΣ
      poso <-- x*20
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΑΝ

ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ
 

Σελίδα 1 από 1 Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]
Powered by phpBB® Forum Software © phpBB Group
http://www.phpbb.com/